Hi @alvinakk,

The primary issue appears to be related to the scale of the geometry. We recommend users to scale your geometry so that the smallest features you care about in the model are \approx \mathcal{O}(1). If I scale your geometry by 0.0001 then I’m able to apply the webcut. We then have a function that will scale your mesh *on export* to recover the actual dimension of your model.

For example:

```
reset
## Create a "small" geometry
bri x 0.000123 # Miles
## Scale geometry from Miles to Feet,
## which gives us an "easy" conversion to remember
## *and* makes our smallest "important" edges a size ~ 1
volume 1 scale 5280
## Mesh the volume
mesh volume 1
block 1 vol 1
## Setup option to scale mesh on export
transform mesh output scale {1/5280} # Uses APREPRO syntax to evaluate 1/5280
## Export the mesh, which will be scaled
export mesh "./transformed_mesh.e" overwrite
```

Note that `transform mesh`

is multiplicative / additive depending on whether you’re doing a scale or translation. So doing `transform mesh output scale 10`

twice will scale by 100, not 10. Make sure to `transform mesh output reset`

to reset.

Anyways, so if I scale your geometry even by just a factor of 0.0001 I am able to successfully cut your geometry:

```
# ----------------------------------------------------------------------
# Set units to SI.
# ----------------------------------------------------------------------
${Units('si')}
#
# ----------------------------------------------------------------------
# Reset geometry.
# ----------------------------------------------------------------------
reset
import Acis "surf_topo_full.sat"
#import Acis "surf_topo_3km.sat"
${idSurf=Id("surface")}
surface {idSurf} name "s_topo"
${idVol=Id("volume")}
volume {idVol} name "v_topo"
${idBody=Id("body")}
body {idBody} name "b_topo"
# ----------------------------------------------------------------------
# Create block for domain.
# ----------------------------------------------------------------------
# Block is 500 km x 500 km x 300 km
${blockLength=1700.0*km}
${blockWidth=1000.0*km}
${blockHeight=300.0*km}
brick x {blockLength} y {blockWidth} z {blockHeight}
${idVol=Id("volume")}
volume {idVol} name "v_domain"
move volume v_domain location 700000 9800000 -100000 include_merged
volume all scale 0.0001
transform mesh output scale 10000
webcut volume v_domain with sheet body b_topo
delete volume {idBody}
# ----------------------------------------------------------------------
# Imprint all volumes, then merge.
# ----------------------------------------------------------------------
imprint all with volume all
merge all
# End of file
```

And here’s a picture of the meshed geometry

And of the bottom volume to show the cut surface