Midsurfacing a Universal Beam and other questions

TBaker · December 5, 2024, 3:29am

Hi,

Obligatory, brand new to forum/ cubit, and I am on the trial period, and have a bunch of basic questions! I have looked through the tutorial slides/ forum posts and couldn’t find much, it all seemed more based around 3D meshing rather than 2D.

Some background, we are trying Cubit to see if we can use this instead of LS Prepost

. The 3D Mesher is amazing, I have had a good amount of success with that, however, I am having a bit of difficult when trying to make 2D meshes.

The first problem I have is that I am trying to mid surface a structure made out of SHS, Universal Beams (UB), and Unequal Angle (UA), so that I can surface mesh it. Auto Midsurface does not seem to work for UB or UA, and when I try using Midsurface, the centre surface extends past the top and bottom surfaces. Then when I try to trim the centre surface back to size using Split, it cuts the surface back, but if I then delete the remainder of the strip, the centre surface goes back to the original dimension. I am assuming that I am doing something wrong, but I don’t know what!

Also, I tried to import a .igs file, but I don’t have that option? Does anyone know if that is a limit on the trial period or just an update or anything?

Lastly, on some UA, there is a radius that leaves no flat surface therefore I can’t delete the radiused face. Could I get some advice on the right tool to make it a orthogonal face, or is the easiest way to just do it in CAD, and then import it?

I hope I haven’t asked to many questions the same as others, although I can’t promise I won’t have more questions!

Thanks,
Ted

Norbert_Hofbauer · December 9, 2024, 8:47pm

Hi @TBaker,
auto midsurface in general does only work when the 3d volume does have 2 logical sides.
Here a link to the documentation .

Just two examples how you could get the midsurfaces.
Starting with the geometry

#!cubit
reset
# lets create beams
create surface rectangle width 1 height 10 zplane 
Surface 1 copy rotate 90 about z 
Surface 1 copy rotate 90 about z 
move surface 2 y -5
move surface 3 y 5
unite surface 1 2 3 

create surface rectangle width 1 height 10 zplane 
Surface 5 copy rotate 90 about z 
move surface 6 x 4.5 y -5
unite surface 5 6
move surface 7 x 20
tweak vertex 17  fillet radius 1 
tweak vertex 24  fillet radius 1 
tweak vertex 25  fillet radius 3

sweep surface 4  vector 0 0 1  distance 20
sweep surface 7  vector 0 0 1  distance 20

Lets first have a look at the left one. I will do a webcut at the bottom. This way i will get 2 scenarios to handle when i midsurface the middle. I will get a surface that needs to be trimmed at the top and extended at the bottom.

webcut volume 1  with sheet extended from surface 13  
create midsurface volume 1  surface 12 18  
create midsurface volume 1  surface 9 11  
create midsurface volume 6  surface 13 15  
delete volume 1 6

To trim the surface at the top i will make use of the tweak curve command. Cubit can tweak curves to a target surface. link to docs

And we can use the same command also to extend the surface.

Then we could alredy imprint, merge and mesh.

tweak curve 76  target surface 35
tweak curve 74  target surface 36
imprint Body 7 8 9
merge Body 7 8 9
mesh surface all in Body 7 8 9

Now the second one. Normally we would remove the features.

But as you noticed, this will get us an error.

But that’s to be expected. There is no adjacent surface to the radius that could be used to remove the gap by extending them. So we use a little workaround here. We will just cut the radius off and delete them and then use an offset to get our initial height and width.

remove surface 23, 25, 27 connected_sets
webcut volume 4  with plane normal to curve 64  fraction 0 from start 
webcut volume 4  with plane normal to curve 68  fraction 0 from end 
delete volume 4, 10
tweak surface 41 53  offset 1

As the resulting volume got 2 logical sides we can use midsurface here and already mesh afterwards.

create midsurface volume 11 auto delete
mesh surface in body 12

The iges import is an extra license. If you want to try it with your trial license you would need to reach out to the sales team if that’s possible. Coreform - Sales

Are you also trying to run ls-dyna models with openradioss? I recently tried a cubit openradioss workflow using the ls-dyna input cards.

TBaker · December 10, 2024, 11:19pm

Hi @Norbert_Hofbauer,

Thanks for your help, with regards to midsurfacing, I have just reverted to using LS-Prepost. It seems to be far stronger for this aspect. Having the method for if I only need to do a couple of UB’s is great, so thank you for that.

With regards to merging, I find it seems to fail fairly regularly, however imprint seems to work. This also seems to give me a mesh that has contiguous nodes, is there any danger that I am unaware of by not using merge? Or does it just merge the Surfaces back into a single Body?

I have never heard of openradioss before, I will have to have a look into it!

Thanks,
Ted

Norbert_Hofbauer · December 11, 2024, 3:21pm

You need imprinting and merging to create a contiguous mesh.

The imprint ensures that the touching bodies will have the same topology. Merging then ensures that the bodies, surfaces, curves, vertices gets connected.

Here a short explanation. First some geometry.

reset
create brick x 1
create brick x 1
move volume 1 x -.5
move volume 2 x .5
split surface 6  offset curve 1  distance 0.5

The left brick has the touching surface splitted.

So if we want to merge directly. The surfaces can’t get merged. The topology for the touching sides is not the same. And the merge request will only merge us the two topological same curves. When we mesh, it looks good on the first view.

merge vol all
mesh vol all

BUT if you run a coincidence check, you will notice that something is not right. We got overlapping nodes.

topology check coincident node volume all tolerance 1.0e-6 draw brief result group 
draw volume 1 add

So we need to first imprint to get the same topology on the touching sides of the volumes.

imprint vol all

Now the right volume has the same topology on the side we want to merge.

If we don’t merge and just mesh. We got overlapping nodes again.

mesh vol all
topology check coincident node volume all tolerance 1.0e-6 draw brief result group 
draw volume 1 add

If we follow the normal cubit workflow then we first imprint and merge afterwards to ensure a contiguous mesh.

The touching surfaces now have the “is merged” property set to yes and the coincident check will tell us that there are no pairs found.

imprint vol all
merge vol all
mesh vol all
topology check coincident node volume all tolerance 1.0e-6 draw brief result group 
draw surface all with is_merged