I want to create 2 circle surfaces with centers and radii on the XOY plane (Z=0), since these 2 circles are small, I need to refine them, too. Then I can make nodesets for each surface s1, s2 in the picture
Thank you so much!
reset
graphics axis type origin on
# Define the scaling factor
#{u = 0.0254}
# Create main cylinder
create cylinder height {12.1*u} radius {0.75*u}
volume 1 move z {12.1/2 * u}
# Create splitting surface
webcut volume all with plane zplane offset {12*0.0254}
webcut volume all with plane xplane
imprint vol all
merge vol all
# Create mesh
volume all size {0.25*u}
volume all scheme tetmesh
surface 16 size 0.001
mesh volume all
graphics mode transparent
@Norbert_Hofbauer
Hi @miraboreasu1,
the easiest way to get your circles on the surface is to imprint one on those surfaces.
After that you can set a mesh size for those small circles, so you don’t actually need to refine after meshing.
reset
graphics axis type origin on
# Define the scaling factor
#{u = 0.0254}
# Create main cylinder
create cylinder height {12.1*u} radius {0.75*u}
volume 1 move z {12.1/2 * u}
# Create splitting surface
webcut volume all with plane zplane offset {12*0.0254}
webcut volume all with plane xplane
#circles
create surface circle radius {u/8} zplane
move Surface 24 location {u/4} 0 0
imprint vol 5 2
move Surface 24 location -{u/4} 0 0
imprint vol 5 4
delete surface 24
imprint vol all
merge vol all
# Create mesh
volume all size {0.25*u}
volume all scheme tetmesh
surface 16 size 0.001
#mesh size circles
surface 25 27 size 0.001
mesh volume all
nodeset 1 add surface 25 27
Thanks @Norbert_Hofbauer, and a follow-up question,
reset
graphics axis type origin on
# Define the scaling factor
#{u = 0.0254}
# Create main cylinder
create cylinder height {6.1*u} radius {0.75*u}
volume 1 move z {6.1/2 * u}
# Create splitting surface
webcut volume all with plane zplane offset {6*0.0254}
webcut volume all with plane xplane
imprint vol all
merge vol all
# Create mesh
volume all size {0.25*u}
volume all scheme tetmesh
surface 16 size 0.001
#mesh size circles
#surface 25 27 size 0.001
mesh volume all
nodeset 1 add surface 17
nodeset 1 name "a"
nodeset 2 add surface 23
nodeset 2 name "b"
- There are overlapping nodes in the middle, I want neither nodeset1 nor nodest2 to include them.
- If I want to delete more, like since the YOZ plane, +x and -x, all the node are excluded from set 1 and 2
Thank you!!
is that what you are looking for?
nodeset 1 add node all in surface 17
nodeset 1 remove node all with x_coord=0
nodeset 2 add in surface 23
nodeset 2 remove node all with x_coord=0
