Coreform Cubit crashes after generating mesh

Coreform Cubit Meshing
#1

When I run the following script, Coreform Cubit 2023.11 crashes without an error.

reset
create sphere radius 100 
mesh surface all
Volume 1 copy move z 210 
mesh vol all
#2

Hi @ksugahar,
thanks for reporting this! We will take a look.

#3

One quick comment to get you unstuck, it’s unnecessary to mesh surface all for spheres if you then plan to mesh vol all. Just do:

reset
create sphere radius 100 
Volume 1 copy move z 210 
mesh vol all
#4

I want the same surface mesh on two spheres.

Finally, I changed it as follows:

create sphere radius 1
webcut volume 1 with plane zplane offset -0.4
imprint all
merge all
volume 1 2 copy move z 2.1 nomesh
create sphere radius 0.2
subtract volume 5 from volume 1 imprint
create sphere radius 0.3
volume 7 move z 2.1
subtract volume 7 from volume 3 imprint
imprint all
merge all
volume all scheme tet
mesh volume 1 2
copy mesh surface 3 onto surface 7 source curve 1 source vertex 1 target curve 3 target vertex 3
copy mesh surface 5 onto surface 8 source curve 1 source vertex 1 target curve 3 target vertex 3
compress
mesh volume all
#5

I’m glad you found a work-around. I was able to replicate the problem.

Here is what is happening in your first case:

  1. The surface gets meshed as a paved mesh.
  2. You then try to mesh the volume which Cubit recognizes as a sphere.
  3. The paved surface mesh is incompatible with the volumetric sphere mesh.
  4. Some developer never accounted for this case happening and you get the crash.

An\ alternative to your mesh using hexes involves splitting and coring the spheres so that they are hex-meshable. I just copied the meshed regions that you wanted exactly the same. It was easier than dealing with scheme copy.

reset
create sphere radius 1
webcut volume 1 with plane zplane offset -0.4
volume 1 2 copy move z 2.1 
create sphere radius 0.2
subtract volume 5 from volume 1 imprint
create sphere radius 0.3
volume 7 move z 2.1
subtract volume 7 from volume 3
webcut volume all with cylinder radius 0.1 axis z
webcut volume 2 4 6 8 plane xplane

imprint all
merge all

vol all size .05

mesh volume with z_coord < 1.0
delete volume 4, 10, 16
Volume 15 2 9 copy move z 2.1
imprint volume with z_coord > 1.1
merge volume with z_coord > 1.1
mesh vol with not is_meshed

Karl
Coreform Cubit Consulting
karl@coremesh.co